Функция substr() в Perl

В языке программирования Perl есть встроенная функция substr(). Эта функция используется при работе со строками. С помощью этой функции можно получить часть строки, или заменить часть строки другой строкой.

Вот пример получения части строки:

▶ Run
#!/usr/bin/perl

my $str = 'Hello, world!';

print "'" . substr($str, 7, 5) . "'";

Эта программа выведет на экран текст 'world'. Вызов функции substr($str, 7, 5) говорит что нужно достать из строки $str пять символов, начиная с седьмой позиции. При таком использовании значение $str не меняется.

При использовании функции substr() с четырьмя аргументами происходит изменение значения переменной. Вот пример использования substr() для замены:

▶ Run
#!/usr/bin/perl

my $str = 'Hello, world!';

print "'" . substr($str, 7, 5, 'you') . "'\n";
print $str;

Вывод программы:

'world'
Hello, you!

Возвращаемое значение при вызове substr($str, 7, 5, 'you') точно такое же как и при вызове substr($str, 7, 5), но вызов с четырьмя аргументами еще и изменил значение переменной. Слово world было заменено на you. Обратите внимание, что замена прошла корректно даже несмотря на то что в изначальном слове и в новом слове разное количество букв.

Аргументы

my $str1 = substr($str, $offset);
my $str2 = substr($str, $offset, $length);
my $str3 = substr($str, $offset, $replacement);

Функции substr() необходимо указать два, три или четыре аргумента.

В том случае если попытаться использовать функцию substr() без аргументов, или с одним аргументом, то будет ошибка:

Not enough arguments for substr at script.pl line 3, near "substr()"
Execution of script.pl aborted due to compilation errors.

При использовании двух аргументов substr($str, $offset) функция возвращает все символы из строки $str начиная с символа на позиции $offset и до конца строки.

При использовании трех аргументов substr($str, $offset, $length) функция возвращает $length символов из строки $str начиная с символа на позиции $offset.

При использовании substr() с двумя или тремя аргументами, изначальное значение строки не меняется.

При использовании четырех аргументов substr($str, $offset, $replacement) функция возвращает то же самое что и в случае трех аргументов, но еще дополнительно заменяет в изначальной строке полученное значение на $replacement.

Возвращаемое значение

Функция substr() может возвращать либо undef, либо строку.

undef возвращается в том случае если попытаться достать элемент из строки по индексу который больше чем длина строки. Вот пример программы, которая возвращает undef:

▶ Run
#!/usr/bin/perl

use Data::Dumper;

my $str = 'Hello, world!';
my $str1 = substr($str, 10000);

warn Dumper $str1;

В том случае если бы в коде программы было бы use warnings;, то программа бы еще дополнительно вывела на экран предупреждение:

substr outside of string at script.pl line 8.

Отрицательные значения $offset

Функции substr() позволяет указывать отрицательные значения для второго аргумента. Пример программы:

▶ Run
#!/usr/bin/perl

my $str = 'Hello, world!';
print substr($str, -3);

На экране появится текст ld! — это последние три символа из строки Hello, world!.

Отрицательный второй аргумент говорит о том что позиция считается с конца строки.

Запись substr($str, -3) совершенно аналогична substr($str, -3, 3).

Отрицательные значения $length

Значение третьего аргумента могут быть отрицательным. Вот пример работы:

▶ Run
#!/usr/bin/perl

use feature qw(say);

my $str = 'Hello, world!';

say substr($str, 7, -1); # world
say substr($str, 7, -2); # worl
say substr($str, 7, -3); # wor

Официальная документация

Вот вывод команды perldoc -f substr:

    substr EXPR,OFFSET,LENGTH,REPLACEMENT
    substr EXPR,OFFSET,LENGTH
    substr EXPR,OFFSET
            Extracts a substring out of EXPR and returns it. First character
            is at offset zero. If OFFSET is negative, starts that far back
            from the end of the string. If LENGTH is omitted, returns
            everything through the end of the string. If LENGTH is negative,
            leaves that many characters off the end of the string.

                my $s = "The black cat climbed the green tree";
                my $color  = substr $s, 4, 5;      # black
                my $middle = substr $s, 4, -11;    # black cat climbed the
                my $end    = substr $s, 14;        # climbed the green tree
                my $tail   = substr $s, -4;        # tree
                my $z      = substr $s, -4, 2;     # tr

            You can use the "substr" function as an lvalue, in which case
            EXPR must itself be an lvalue. If you assign something shorter
            than LENGTH, the string will shrink, and if you assign something
            longer than LENGTH, the string will grow to accommodate it. To
            keep the string the same length, you may need to pad or chop
            your value using "sprintf".

            If OFFSET and LENGTH specify a substring that is partly outside
            the string, only the part within the string is returned. If the
            substring is beyond either end of the string, "substr" returns
            the undefined value and produces a warning. When used as an
            lvalue, specifying a substring that is entirely outside the
            string raises an exception. Here's an example showing the
            behavior for boundary cases:

                my $name = 'fred';
                substr($name, 4) = 'dy';         # $name is now 'freddy'
                my $null = substr $name, 6, 2;   # returns "" (no warning)
                my $oops = substr $name, 7;      # returns undef, with warning
                substr($name, 7) = 'gap';        # raises an exception

            An alternative to using "substr" as an lvalue is to specify the
            replacement string as the 4th argument. This allows you to
            replace parts of the EXPR and return what was there before in
            one operation, just as you can with "splice".

                my $s = "The black cat climbed the green tree";
                my $z = substr $s, 14, 7, "jumped from";    # climbed
                # $s is now "The black cat jumped from the green tree"

            Note that the lvalue returned by the three-argument version of
            "substr" acts as a 'magic bullet'; each time it is assigned to,
            it remembers which part of the original string is being
            modified; for example:

                my $x = '1234';
                for (substr($x,1,2)) {
                    $_ = 'a';   print $x,"\n";    # prints 1a4
                    $_ = 'xyz'; print $x,"\n";    # prints 1xyz4
                    $x = '56789';
                    $_ = 'pq';  print $x,"\n";    # prints 5pq9
                }

            With negative offsets, it remembers its position from the end of
            the string when the target string is modified:

                my $x = '1234';
                for (substr($x, -3, 2)) {
                    $_ = 'a';   print $x,"\n";    # prints 1a4, as above
                    $x = 'abcdefg';
                    print $_,"\n";                # prints f
                }

            Prior to Perl version 5.10, the result of using an lvalue
            multiple times was unspecified. Prior to 5.16, the result with
            negative offsets was unspecified.

Связанные темы

Другие статьи