A função substr() em Perl

Na linguagem de programação Perl possui a função de substr(). Esta função é utilizada quando se trabalha com cadeias de caracteres. Com esta função, você pode obter uma parte de uma cadeia, ou substituir a peça de comando com outra string.

Aqui está um exemplo de obtenção de peças de comando:

▶ Run
#!/usr/bin/perl

my $str = 'Hello, world!';

print "'" . substr($str, 7, 5) . "'";

Este programa irá imprimir na tela o texto 'world'. A chamada de função substr($str, 7, 5) diz que é necessário recuperar a partir de uma linha $str cinco caracteres, começando com a sétima posição. Com o uso de o valor $str não muda.

Quando você usa a função substr() , com quatro argumentos ocorre a mudança do valor da variável. Eis um exemplo do uso substr() para a substituição:

▶ Run
#!/usr/bin/perl

my $str = 'Hello, world!';

print "'" . substr($str, 7, 5, 'you') . "'\n";
print $str;

A saída do programa:

'world'
Hello, you!

O valor de retorno ao chamar substr($str, 7, 5, 'you') é exatamente a mesma como e quando chamar substr($str, 7, 5), mas a chamada com quatro argumentos ainda e mudou o valor de uma variável. A palavra world foi substituído pelo you. Tenha em atenção, que a substituição passou corretamente, mesmo apesar do fato de que, no original, a palavra e a palavra nova a um número diferente de letras.

Argumentos

my $str1 = substr($str, $offset);
my $str2 = substr($str, $offset, $length);
my $str3 = substr($str, $offset, $replacement);

A função substr() é necessário especificar dois, três ou quatro argumentos.

No caso de se tentar usar o recurso de substr() sem argumentos, ou com um o argumento, então o erro será:

Not enough arguments for substr at script.pl line 3, near "substr()"
Execution of script.pl aborted due to compilation errors.

Quando você usa dois argumentos substr($str, $offset) a função retorna todos os caracteres da linha $str começando com o caractere na posição $offset e até o final da linha.

Quando utiliza três argumentos substr($str, $offset, $length) a função retorna $length caracteres a partir de uma linha $str começando com o caractere na posição $offset.

Quando você usa o substr() , com dois ou três argumentos, o valor inicial do comando não muda.

Quando você usa quatro argumentos substr($str, $offset, $replacement)função retorna o mesmo que, no caso de três argumentos, mas ainda avançado substitui o original de comandos, o valor obtido no $replacement.

O valor de retorno

A função substr() pode retornar qualquer undef, ou uma cadeia de caracteres.

undef está de volta em caso de tentar se apossar de um item de linha por um índice que é maior do que o comprimento da cadeia. Aqui está um exemplo de um programa que retorna undef:

▶ Run
#!/usr/bin/perl

use Data::Dumper;

my $str = 'Hello, world!';
my $str1 = substr($str, 10000);

warn Dumper $str1;

No caso seria no código do programa seria use warnings;, o programa ainda seria adicionalmente, trouxe para a tela de aviso:

substr outside of string at script.pl line 8.

Valores negativos $offset

A função substr() permite especificar valores negativos para o segundo argumento. Exemplo de programa:

▶ Run
#!/usr/bin/perl

my $str = 'Hello, world!';
print substr($str, -3);

Na tela aparecerá o texto ld! — é o mais recente de três caracteres a partir de uma linha Hello, world!.

Negativo o segundo argumento diz-se que a posição é considerada com o fim da linha.

A entrada substr($str, -3) totalmente semelhante substr($str, -3, 3).

Valores negativos $length

O valor do terceiro argumento pode ser negativo. Aqui está um exemplo de trabalho:

▶ Run
#!/usr/bin/perl

use feature qw(say);

my $str = 'Hello, world!';

say substr($str, 7, -1); # world
say substr($str, 7, -2); # worl
say substr($str, 7, -3); # wor

A documentação oficial

Aqui está a saída do comando perldoc -f substr:

    substr EXPR,OFFSET,LENGTH,REPLACEMENT
    substr EXPR,OFFSET,LENGTH
    substr EXPR,OFFSET
            Extracts a substring out of EXPR and returns it. First character
            is at offset zero. If OFFSET is negative, starts that far back
            from the end of the string. If LENGTH is omitted, returns
            everything through the end of the string. If LENGTH is negative,
            leaves that many characters off the end of the string.

                my $s = "The black cat climbed the green tree";
                my $color  = substr $s, 4, 5;      # black
                my $middle = substr $s, 4, -11;    # black cat climbed the
                my $end    = substr $s, 14;        # climbed the green tree
                my $tail   = substr $s, -4;        # tree
                my $z      = substr $s, -4, 2;     # tr

            You can use the "substr" function as an lvalue, in which case
            EXPR must itself be an lvalue. If you assign something shorter
            than LENGTH, the string will shrink, and if you assign something
            longer than LENGTH, the string will grow to accommodate it. To
            keep the string the same length, you may need to pad or chop
            your value using "sprintf".

            If OFFSET and LENGTH specify a substring that is partly outside
            the string, only the part within the string is returned. If the
            substring is beyond either end of the string, "substr" returns
            the undefined value and produces a warning. When used as an
            lvalue, specifying a substring that is entirely outside the
            string raises an exception. Here's an example showing the
            behavior for boundary cases:

                my $name = 'fred';
                substr($name, 4) = 'dy';         # $name is now 'freddy'
                my $null = substr $name, 6, 2;   # returns "" (no warning)
                my $oops = substr $name, 7;      # returns undef, with warning
                substr($name, 7) = 'gap';        # raises an exception

            An alternative to using "substr" as an lvalue is to specify the
            replacement string as the 4th argument. This allows you to
            replace parts of the EXPR and return what was there before in
            one operation, just as you can with "splice".

                my $s = "The black cat climbed the green tree";
                my $z = substr $s, 14, 7, "jumped from";    # climbed
                # $s is now "The black cat jumped from the green tree"

            Note that the lvalue returned by the three-argument version of
            "substr" acts as a 'magic bullet'; each time it is assigned to,
            it remembers which part of the original string is being
            modified; for example:

                my $x = '1234';
                for (substr($x,1,2)) {
                    $_ = 'a';   print $x,"\n";    # prints 1a4
                    $_ = 'xyz'; print $x,"\n";    # prints 1xyz4
                    $x = '56789';
                    $_ = 'pq';  print $x,"\n";    # prints 5pq9
                }

            With negative offsets, it remembers its position from the end of
            the string when the target string is modified:

                my $x = '1234';
                for (substr($x, -3, 2)) {
                    $_ = 'a';   print $x,"\n";    # prints 1a4, as above
                    $x = 'abcdefg';
                    print $_,"\n";                # prints f
                }

            Prior to Perl version 5.10, the result of using an lvalue
            multiple times was unspecified. Prior to 5.16, the result with
            negative offsets was unspecified.

Temas relacionados

Outros artigos