Funkcja substr() w Perl

W języku programowania Perl jest wbudowana funkcja substr(). Funkcja ta jest używana podczas pracy z wierszami. Za pomocą tej funkcji można uzyskać część wiersza, lub wymienić część wiersza innego wiersza.

Oto przykład uzyskać części wiersza:

▶ Run
#!/usr/bin/perl

my $str = 'Hello, world!';

print "'" . substr($str, 7, 5) . "'";

Ten program wyświetla na ekranie tekst 'world'. Wywołanie funkcji substr($str, 7, 5) mówi, że trzeba zdobyć z wiersza $str pięć znaków, począwszy od siódmej pozycji. Przy takim użyciu wartość $str się nie zmienia.

Podczas korzystania z funkcji substr() z czterema argumentami następuje zmiana wartości zmiennej. Oto przykład użycia substr() do wymiany:

▶ Run
#!/usr/bin/perl

my $str = 'Hello, world!';

print "'" . substr($str, 7, 5, 'you') . "'\n";
print $str;

Wyjście z programu:

'world'
Hello, you!

Wartość zwracana przez wywołanie substr($str, 7, 5, 'you') jest dokładnie taka sama jak przy wywołaniu substr($str, 7, 5), ale to wyzwanie, z czterema argumentami jeszcze i zmienił wartość zmiennej. Słowo world został zastąpiony na you. Należy uwagę, że wymiana przebiegła prawidłowo, nawet pomimo faktu, że w oryginalnym słowie i w nowym słowie różną liczbę liter.

Argumenty

my $str1 = substr($str, $offset);
my $str2 = substr($str, $offset, $length);
my $str3 = substr($str, $offset, $replacement);

Funkcje substr() należy podać dwa, trzy lub cztery argumenty.

W tym przypadku spróbować użyć funkcji substr() bez argumentów, lub z jednym argumentem, to będzie błąd:

Not enough arguments for substr at script.pl line 3, near "substr()"
Execution of script.pl aborted due to compilation errors.

W przypadku korzystania z dwóch argumentów substr($str, $offset) funkcja zwraca wszystkie znaki z wiersza $str począwszy od znaku na pozycji $offset i do końca wiersza.

Przy użyciu trzech argumentów substr($str, $offset, $length) funkcja zwraca $length znaków z ciągu $str począwszy od znaku na pozycji $offset.

Podczas korzystania z substr() z dwoma lub trzema argumentami, pierwotne znaczenie wiersza nie zmienia się.

Przy użyciu czterech argumentów substr($str, $offset, $replacement)funkcja zwraca to samo, co w przypadku trzech argumentów, ale jeszcze dodatkowo zastępuje w pierwotnej linii otrzymaną wartość na $replacement.

Wartość zwracana

Funkcja substr() może zwrócić lub undef, albo wiersz.

undef zwrotowi w przypadku, gdy starają się zdobyć element z paska w indeksie który jest większy niż długość ciągu. Oto przykład programu, który zwraca undef:

▶ Run
#!/usr/bin/perl

use Data::Dumper;

my $str = 'Hello, world!';
my $str1 = substr($str, 10000);

warn Dumper $str1;

W przypadku gdyby w kodzie programu byłoby use warnings;, to program by jeszcze dodatkowo wprowadziła na ekran ostrzeżenie:

substr outside of string at script.pl line 8.

Ujemne wartości $offset

Funkcje substr() umożliwia określenie wartości ujemne dla drugiego argumentu. Przykład programu:

▶ Run
#!/usr/bin/perl

my $str = 'Hello, world!';
print substr($str, -3);

Na ekranie pojawi się tekst ld! — to ostatnie trzy znaki z wiersza Hello, world!.

Negatywny drugi argument mówi o tym, że pozycja jest z końca wiersza.

Nagrywanie substr($str, -3) zupełnie podobna do substr($str, -3, 3).

Ujemne wartości $length

Wartość trzeciego argumentu może być ujemna. Oto przykład działania:

▶ Run
#!/usr/bin/perl

use feature qw(say);

my $str = 'Hello, world!';

say substr($str, 7, -1); # world
say substr($str, 7, -2); # worl
say substr($str, 7, -3); # wor

Oficjalna dokumentacja

Oto wynik polecenia perldoc -f substr:

    substr EXPR,OFFSET,LENGTH,REPLACEMENT
    substr EXPR,OFFSET,LENGTH
    substr EXPR,OFFSET
            Extracts a substring out of EXPR and returns it. First character
            is at offset zero. If OFFSET is negative, starts that far back
            from the end of the string. If LENGTH is omitted, returns
            everything through the end of the string. If LENGTH is negative,
            leaves that many characters off the end of the string.

                my $s = "The black cat climbed the green tree";
                my $color  = substr $s, 4, 5;      # black
                my $middle = substr $s, 4, -11;    # black cat climbed the
                my $end    = substr $s, 14;        # climbed the green tree
                my $tail   = substr $s, -4;        # tree
                my $z      = substr $s, -4, 2;     # tr

            You can use the "substr" function as an lvalue, in which case
            EXPR must itself be an lvalue. If you assign something shorter
            than LENGTH, the string will shrink, and if you assign something
            longer than LENGTH, the string will grow to accommodate it. To
            keep the string the same length, you may need to pad or chop
            your value using "sprintf".

            If OFFSET and LENGTH specify a substring that is partly outside
            the string, only the part within the string is returned. If the
            substring is beyond either end of the string, "substr" returns
            the undefined value and produces a warning. When used as an
            lvalue, specifying a substring that is entirely outside the
            string raises an exception. Here's an example showing the
            behavior for boundary cases:

                my $name = 'fred';
                substr($name, 4) = 'dy';         # $name is now 'freddy'
                my $null = substr $name, 6, 2;   # returns "" (no warning)
                my $oops = substr $name, 7;      # returns undef, with warning
                substr($name, 7) = 'gap';        # raises an exception

            An alternative to using "substr" as an lvalue is to specify the
            replacement string as the 4th argument. This allows you to
            replace parts of the EXPR and return what was there before in
            one operation, just as you can with "splice".

                my $s = "The black cat climbed the green tree";
                my $z = substr $s, 14, 7, "jumped from";    # climbed
                # $s is now "The black cat jumped from the green tree"

            Note that the lvalue returned by the three-argument version of
            "substr" acts as a 'magic bullet'; each time it is assigned to,
            it remembers which part of the original string is being
            modified; for example:

                my $x = '1234';
                for (substr($x,1,2)) {
                    $_ = 'a';   print $x,"\n";    # prints 1a4
                    $_ = 'xyz'; print $x,"\n";    # prints 1xyz4
                    $x = '56789';
                    $_ = 'pq';  print $x,"\n";    # prints 5pq9
                }

            With negative offsets, it remembers its position from the end of
            the string when the target string is modified:

                my $x = '1234';
                for (substr($x, -3, 2)) {
                    $_ = 'a';   print $x,"\n";    # prints 1a4, as above
                    $x = 'abcdefg';
                    print $_,"\n";                # prints f
                }

            Prior to Perl version 5.10, the result of using an lvalue
            multiple times was unspecified. Prior to 5.16, the result with
            negative offsets was unspecified.

Tematy pokrewne

Inne artykuły