Funkcja srand() w Perl

W języku programowania Perl jest wbudowana funkcja srand().

Ta funkcja służy do ustawiania lub w celu uzyskania numeru kolejności wartości liczbowych z którą zwraca funkcja rand().

Najczęściej funkcja srand() jest używany w testach, aby przy każdym uruchomienie testu funkcja rand() przyprowadziła te same wartości.

Oto przykład kodu:

▶ Run
#!/usr/bin/perl

use strict;
use warnings;
use feature qw(say);

srand(16);

say int(rand(10));
say int(rand(10));
say int(rand(10));
say int(rand(10));
say int(rand(10));

Wynik działania programu to zawsze jedne i te same 5 cyfr:

1
0
9
3
3

Program wykorzystuje int(rand(10)) , aby uzyskać losową liczbę od 0(włącznie), do 9(włącznie).

W kodzie jest wyzwanie srand(16);. To wyzwanie instaluje że funkcja rand() musi zwrócić liczby z sekwencyjną sekwencji pokój 16. Dlatego każde uruchomienie tego programu prowadzi do tego samego wyniku. Gdyby w tym programie nie było wywołanie funkcji srand(), to różne uruchomienia programu mogą zwrócić różne wartości.

Argumenty

Funkcję srand() bez argumentów można użyć, albo przekazać jej dokładnie jeden argument.

W przypadku, gdy przekazać jej więcej niż jeden argument, to będzie błąd:

Too many arguments for srand at script.pl line 3, near "2)"
Execution of script.pl aborted due to compilation errors.

Funkcja nie wykorzystuje zmienną $_. Jeśli istnieje potrzeba jej użyć, to trzeba ją wyraźnie przekazać do funkcji srand($_);.

Funkcja spodziewa się uzyskać liczbę jako wartość argumentu. Jeśli funkcja ma nie liczba, to ona prowadzi go do grona.

Funkcja odrzuca część dziesiętną i znakiem. srand(-2.9) — to samo co i srand(2). Oto przykład kodu, który to pokazuje:

▶ Run
#!/usr/bin/perl

use strict;
use warnings;

foreach my $n (-2, 2, 2.1, 2.9, -2.1, -2.9) {
    my $real_n = srand($n);
    my @arr;
    foreach (1..5) {
        push @arr, int(rand(10));
    }
    printf "%4s  %s  (%s)\n", $n, $real_n, join(', ', @arr);
}

Wartość zwracana

Począwszy od wersji Perl 5.14 funkcja srand() zawsze zwraca liczbę od 1 do 4294967296, albo wiersz 0 but true. Ta liczba to numer sekwencji, która jest używana w funkcji rand().

Jeśli funkcję srand() wywołać bez argumentów, to przywróci pokój sekwencje, który został zainstalowany automatycznie.

Jeśli wywołać funkcję z argumentem, to zwróci wartość numeru sekwencji, które zostało zainstalowane z tego argumentu:

▶ Run
#!/usr/bin/perl

use feature qw(say);

say srand(1573); # 1573
say srand(-2.9); # 2

Ciekawe co dla sekwencji z numerem 0 funkcja zwraca ciąg znaków 0 but true:

▶ Run
#!/usr/bin/perl

print srand(0);

Do wersji Perl 5.14 funkcja srand() zawsze zwracało liczba 1.

Oficjalna dokumentacja

Oto wynik polecenia perldoc -f srand:

    srand EXPR
    srand   Sets and returns the random number seed for the "rand" operator.

            The point of the function is to "seed" the "rand" function so
            that "rand" can produce a different sequence each time you run
            your program. When called with a parameter, "srand" uses that
            for the seed; otherwise it (semi-)randomly chooses a seed. In
            either case, starting with Perl 5.14, it returns the seed. To
            signal that your code will work *only* on Perls of a recent
            vintage:

                use 5.014;  # so srand returns the seed

            If "srand" is not called explicitly, it is called implicitly
            without a parameter at the first use of the "rand" operator.
            However, there are a few situations where programs are likely to
            want to call "srand". One is for generating predictable results,
            generally for testing or debugging. There, you use
            "srand($seed)", with the same $seed each time. Another case is
            that you may want to call "srand" after a "fork" to avoid child
            processes sharing the same seed value as the parent (and
            consequently each other).

            Do not call "srand()" (i.e., without an argument) more than once
            per process. The internal state of the random number generator
            should contain more entropy than can be provided by any seed, so
            calling "srand" again actually *loses* randomness.

            Most implementations of "srand" take an integer and will
            silently truncate decimal numbers. This means "srand(42)" will
            usually produce the same results as "srand(42.1)". To be safe,
            always pass "srand" an integer.

            A typical use of the returned seed is for a test program which
            has too many combinations to test comprehensively in the time
            available to it each run. It can test a random subset each time,
            and should there be a failure, log the seed used for that run so
            that it can later be used to reproduce the same results.

            "rand" is not cryptographically secure. You should not rely on
            it in security-sensitive situations. As of this writing, a
            number of third-party CPAN modules offer random number
            generators intended by their authors to be cryptographically
            secure, including: Data::Entropy, Crypt::Random,
            Math::Random::Secure, and Math::TrulyRandom.

Tematy pokrewne

Inne artykuły