समारोह substr() पर्ल में

में पर्ल प्रोग्रामिंग भाषा में बनाया गया है एक समारोह substr(). आप कर सकते हैं इस समारोह का उपयोग के साथ काम कर जब तार. इस समारोह का उपयोग कर, आप प्राप्त कर सकते हैं एक स्ट्रिंग का हिस्सा है, या करने के लिए का हिस्सा की जगह के साथ एक स्ट्रिंग एक स्ट्रिंग.

यहाँ एक उदाहरण है प्राप्त करने के एक स्ट्रिंग का हिस्सा:

▶ Run
#!/usr/bin/perl

my $str = 'Hello, world!';

print "'" . substr($str, 7, 5) . "'";

इस कार्यक्रम को प्रदर्शित करता है पाठ 'world'. कॉल समारोह substr($str, 7, 5)कहते हैं आप की जरूरत है पाने के लिए लाइन से $str के पांच अक्षरों से शुरू होने वाले सातवें स्थान. में इस का उपयोग करें मूल्य $str परिवर्तन नहीं करता है.

जब का उपयोग कर substr() के साथ चार तर्क परिवर्तन की एक चर के मूल्य. यहाँ है एक उदाहरण का उपयोग कर substr() को बदलने के लिए:

▶ Run
#!/usr/bin/perl

my $str = 'Hello, world!';

print "'" . substr($str, 7, 5, 'you') . "'\n";
print $str;

के उत्पादन कार्यक्रम:

'world'
Hello, you!

वापसी मान जब आप कॉल substr($str, 7, 5, 'you') है बिल्कुल उसी के रूप में जब आप कॉल substr($str, 7, 5), लेकिन कॉल के साथ चार तर्क और यहां तक कि बदल गया है, चर के मूल्य. शब्द world द्वारा बदल दिया गया था you. कृपया ध्यान दें कि प्रतिस्थापन सही था कि इस तथ्य के बावजूद मूल शब्द में और नए शब्द का एक अलग संख्या में पत्र.

तर्क

my $str1 = substr($str, $offset);
my $str2 = substr($str, $offset, $length);
my $str3 = substr($str, $offset, $replacement);

समारोह substr() , आप निर्दिष्ट करना चाहिए, दो, तीन, या चार तर्क.

मामले में यदि आप की कोशिश करने के लिए इस समारोह का उपयोग करें substr() कोई तर्क के साथ, या के साथ एक तर्क, यह त्रुटि होगा:

Not enough arguments for substr at script.pl line 3, near "substr()"
Execution of script.pl aborted due to compilation errors.

का उपयोग करते समय दो तर्क substr($str, $offset) समारोह रिटर्न सभी वर्ण स्ट्रिंग से $str के साथ शुरू करने के चरित्र पर स्थिति $offset के लिए, पंक्ति के अंत में.

जब का उपयोग कर तीन तर्क substr($str, $offset, $length) समारोह रिटर्न $length पात्रों में से एक स्ट्रिंग $str के साथ शुरू करने के चरित्र पर स्थिति $offset.

जब का उपयोग कर substr() के साथ दो या तीन तर्क, मूल स्ट्रिंग मान परिवर्तन नहीं करता है.

यदि आप का उपयोग चार तर्क substr($str, $offset, $replacement)समारोह रिटर्न के रूप में एक ही मामले के तीन तर्क, लेकिन इसके साथ ही जगह में मूल स्ट्रिंग, मूल्य के द्वारा प्राप्त किया $replacement.

वापसी मान

समारोह substr() लौट सकते हैं या तो undef, या एक स्ट्रिंग है.

undef में लौट रहा है, तो आप प्राप्त करने की कोशिश तत्व से स्ट्रिंग सूचकांक की तुलना में अधिक है जो स्ट्रिंग की लंबाई. यहाँ एक नमूना कार्यक्रम है कि रिटर्न undef:

▶ Run
#!/usr/bin/perl

use Data::Dumper;

my $str = 'Hello, world!';
my $str1 = substr($str, 10000);

warn Dumper $str1;

घटना में यदि में प्रोग्राम कोड के लिए किया जाएगा use warnings;, कार्यक्रम अभी भी होगा इसके साथ ही डाल पर चेतावनी स्क्रीन:

substr outside of string at script.pl line 8.

नकारात्मक मूल्यों $offset

समारोह substr() आप की अनुमति देता है निर्दिष्ट करने के लिए नकारात्मक मूल्यों के लिए दूसरा तर्क है । उदाहरण के लिए कार्यक्रम:

▶ Run
#!/usr/bin/perl

my $str = 'Hello, world!';
print substr($str, -3);

स्क्रीन प्रदर्शित करेगा पाठ ld! पिछले तीन पात्रों में से स्ट्रिंग Hello, world!.

एक नकारात्मक दूसरा तर्क पता चलता है कि स्थिति से गिना जाता है पंक्ति के अंत में.

प्रविष्टि substr($str, -3) काफी समान है substr($str, -3, 3).

नकारात्मक मूल्यों $length

मूल्य का तीसरा तर्क नकारात्मक हो सकता है. यहाँ का उदाहरण है:

▶ Run
#!/usr/bin/perl

use feature qw(say);

my $str = 'Hello, world!';

say substr($str, 7, -1); # world
say substr($str, 7, -2); # worl
say substr($str, 7, -3); # wor

सरकारी दस्तावेज

यहाँ उत्पादन के आदेश perldoc -f substr:

    substr EXPR,OFFSET,LENGTH,REPLACEMENT
    substr EXPR,OFFSET,LENGTH
    substr EXPR,OFFSET
            Extracts a substring out of EXPR and returns it. First character
            is at offset zero. If OFFSET is negative, starts that far back
            from the end of the string. If LENGTH is omitted, returns
            everything through the end of the string. If LENGTH is negative,
            leaves that many characters off the end of the string.

                my $s = "The black cat climbed the green tree";
                my $color  = substr $s, 4, 5;      # black
                my $middle = substr $s, 4, -11;    # black cat climbed the
                my $end    = substr $s, 14;        # climbed the green tree
                my $tail   = substr $s, -4;        # tree
                my $z      = substr $s, -4, 2;     # tr

            You can use the "substr" function as an lvalue, in which case
            EXPR must itself be an lvalue. If you assign something shorter
            than LENGTH, the string will shrink, and if you assign something
            longer than LENGTH, the string will grow to accommodate it. To
            keep the string the same length, you may need to pad or chop
            your value using "sprintf".

            If OFFSET and LENGTH specify a substring that is partly outside
            the string, only the part within the string is returned. If the
            substring is beyond either end of the string, "substr" returns
            the undefined value and produces a warning. When used as an
            lvalue, specifying a substring that is entirely outside the
            string raises an exception. Here's an example showing the
            behavior for boundary cases:

                my $name = 'fred';
                substr($name, 4) = 'dy';         # $name is now 'freddy'
                my $null = substr $name, 6, 2;   # returns "" (no warning)
                my $oops = substr $name, 7;      # returns undef, with warning
                substr($name, 7) = 'gap';        # raises an exception

            An alternative to using "substr" as an lvalue is to specify the
            replacement string as the 4th argument. This allows you to
            replace parts of the EXPR and return what was there before in
            one operation, just as you can with "splice".

                my $s = "The black cat climbed the green tree";
                my $z = substr $s, 14, 7, "jumped from";    # climbed
                # $s is now "The black cat jumped from the green tree"

            Note that the lvalue returned by the three-argument version of
            "substr" acts as a 'magic bullet'; each time it is assigned to,
            it remembers which part of the original string is being
            modified; for example:

                my $x = '1234';
                for (substr($x,1,2)) {
                    $_ = 'a';   print $x,"\n";    # prints 1a4
                    $_ = 'xyz'; print $x,"\n";    # prints 1xyz4
                    $x = '56789';
                    $_ = 'pq';  print $x,"\n";    # prints 5pq9
                }

            With negative offsets, it remembers its position from the end of
            the string when the target string is modified:

                my $x = '1234';
                for (substr($x, -3, 2)) {
                    $_ = 'a';   print $x,"\n";    # prints 1a4, as above
                    $x = 'abcdefg';
                    print $_,"\n";                # prints f
                }

            Prior to Perl version 5.10, the result of using an lvalue
            multiple times was unspecified. Prior to 5.16, the result with
            negative offsets was unspecified.

संबंधित विषयों

अन्य लेख